home *** CD-ROM | disk | FTP | other *** search
/ CU Amiga Super CD-ROM 18 / CU Amiga Magazine's Super CD-ROM 18 (1997)(EMAP Images)(GB)[!][issue 1998-01].iso / InitCD < prev    next >
AmigaDOS Script File  |  1997-11-18  |  5KB  |  179 lines
  1. .key arg
  2. .bra {
  3. .ket }
  4.  
  5. ; CUCD Init Script
  6. ;
  7. ; Set up assigns etc. both for users booting from the CD and from  HD
  8. ;
  9. ; Version 1.1 - Changed jpegtmp
  10. ;
  11. ; Version 1.2 - Added uninit option
  12. ;
  13. ; Version 1.3 - Added CHECK argument and link to Prefs editor
  14.  
  15. Assign CUCD: :
  16.  
  17. ;;; Make some commands resident to speed up things on CD32s in particular
  18. Resident >NIL: CUCD:C/RequestChoice PURE
  19. Resident >NIL: CUCD:rexxc/rx PURE
  20. Resident >NIL: CUCD:C/Version PURE
  21. ;;;
  22. ;;; Exit if InitCD has been run, otherwise ask
  23. If {arg} EQ "CHECK"
  24.     If $CDInit EQ TRUE
  25.         Skip END
  26.     Else
  27.         set init `CUCD:C/RequestChoice "CU Amiga CD" "InitCD needs to be run first*NWould you like to run it now?" "Yes|No"`
  28.         If $init EQ 0
  29.             Skip END
  30.             EndIf
  31.         EndIf
  32.     EndIf
  33. ;;;
  34. ;;; Give option to run UninitCD
  35. If $CDInit EQ TRUE
  36.     If $CDBoot EQ TRUE          ; don't run UninitCD if booted from CD
  37.         CUCD:C/RequestChoice >NIL: "CU Amiga CD" "You do not need to run InitCD*Nwhen you have booted from the CD" "OK" 
  38.         Skip END
  39.         EndIf
  40.     set remass `CUCD:C/RequestChoice "InitCD" "You have already run InitCD once.*NDo you wish to remove the assigns and paths added before?" "Remove|Cancel"`
  41.     If $remass EQ 1
  42.         execute UnInitCD
  43.         EndIf
  44.     Skip END
  45.     EndIf
  46. ;;;
  47. ;;; Set some system assigns and paths
  48. Assign WWW:             CUCD:CUCD/WWW
  49. Assign tcpdldir:        CUCD:CUCD/WWW
  50. Assign GM:              CUCD:CDsupport/GMPlay ADD
  51. Assign CUCDNews:        CUCD:CUCD/Online/News
  52. Assign Twist:           CUCD:CUCD/Magazine/Issues
  53. Assign TwistIcon:       Twist:Icons
  54. Path GM: ADD
  55. ;;;
  56. ;;; Add MUI if no MUI installed.
  57. Assign MUI: EXISTS >NIL:
  58. IF WARN
  59.     Assign MUI:    CUCD:CDsupport/MUI
  60.     Assign Libs:   MUI:Libs ADD
  61.     Assign LOCALE: MUI:Locale ADD
  62.     Assign HELP: exists >NIL:
  63.     If NOT WARN
  64.         Dir >NIL: HELP:
  65.         EndIf
  66.     Assign HELP:   MUI:Docs ADD
  67. Else
  68.     :C/UpdateCopy >NIL: CUCD:CDsupport/MUI/Libs/MUI/Icon.mcc MUI:Libs/MUI CLONE DEEP
  69.     EndIf
  70. ;;;
  71. ;;; Set assigns and paths for programs on this CD
  72. Execute CUCD:S/ThisCD
  73. ;;;
  74. ;;;BEGIN ClassAct
  75. CUCD:C/CAPrefs >NIL:
  76. ;;;END ClassAct
  77. ;;; Start arexx if not running
  78. CUCD:rexxc/rx "address command" >NIL:
  79. If WARN
  80.     CUCD:System/RexxMast >NIL:
  81.     EndIf
  82. ;;;
  83. ;;; Commands to be run only if booting from CD
  84. IF $CDBoot EQ TRUE
  85.     Run <NIL: >NIL: CUCD:C/NewIcons
  86.     CUCD:C/DefIcons
  87.  
  88.     ; Run these only if booting from a real CD32
  89.     Version >NIL:
  90.     if $kickstart EQ "40.60"
  91.         C:CD2XSpeed
  92.         C:NoReset
  93.         endif
  94.  
  95.     ; Allow alternative screenmodes
  96.     joypad >NIL:
  97.     joypad REW FWD GREEN
  98.     if WARN
  99.         :Storage/Monitors/NTSC
  100.         :Prefs/ScreenMode from :Prefs/Presets/NTSC USE
  101.         :Prefs/Input from :Prefs/Presets/USkey USE
  102.         setenv VisageOpts MONITOR=NTSC
  103.         endif
  104.     joypad REW FWD BLUE
  105.     if WARN
  106.         :Storage/Monitors/DblPAL
  107.         :Prefs/ScreenMode from :Prefs/Presets/VGA USE
  108.         setenv VisageOpts MONITOR=DblPAL
  109.         endif
  110. ;;;
  111. ;;; All this is only needed when not booting from the CD
  112. Else
  113.     Run >NIL: RequestChoice "InitCD" "Setting up some assigns and paths to run software from the CD.*NIf you wish to remove the CD from the drive, run InitCD again,*Notherwise the icon will stay on the Workbench." " OK "
  114.     Assign DEVS:    CUCD:Devs ADD
  115.     Assign Fonts:   CUCD:Fonts ADD
  116.     Assign Libs:    CUCD:Libs ADD
  117.     Assign L:       CUCD:L ADD
  118.     Assign S:       CUCD:S ADD
  119.     Assign LIBS:    CUCD:Classes ADD
  120.     Path CUCD:C CUCD:CDsupport CUCD:System CUCD:Utilities CUCD:S CUCD:Rexxc ADD
  121.  
  122.     ; Make environment variables defined on CD available to system
  123.     Failat 21
  124.     Assign >NIL: ENV: CUCD:Prefs/Env-Archive ADD
  125.     ; For HappyENV users
  126.     If FAIL     
  127.         Assign >NIL: ENVARC: CUCD:Prefs/Env-Archive ADD
  128.         EndIf
  129.  
  130.     ;Start NewIcons if not already running
  131.     If $NoNewIcons NOT EQ TRUE
  132.         CUCD:C/isnirunning
  133.         If NOT WARN
  134.             Run <NIL: >NIL: CUCD:C/NewIcons
  135.             CUCD:C/DefIcons
  136.             EndIf
  137.         EndIf
  138.  
  139.     ; Update workbench paths unless running Directory Opus 5.11 or 5.5 in WBR mode
  140.     Version >NIL: C:LoadWB 43
  141.     If WARN
  142.        C:LoadWB NEWPATH
  143.     Else
  144.         Version >NIL: C:LoadWB 60
  145.         If NOT WARN
  146.             C:LoadWB NEWPATH
  147.             EndIf
  148.         EndIf
  149.  
  150.     ; Give option for setting CD preferences
  151.     Version >NIL: version 37
  152.     If NOT WARN
  153.         If NOT EXISTS ENV:IDer.prefs
  154.             set edit `RequestChoice "CU Amiga CD" "CUCD now has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
  155.             If $edit EQ 1
  156.                 cd CUCD:S
  157.                 :RexxC/MuiRexx CUCDPrefs.mrx port CDPREFS
  158.             else
  159.                 RequestChoice >NIL: "CU Amiga CD" "You can run CUCD preferences at any time.*NIt is in the Prefs drawer of the CD" "OK"
  160.                 EndIf
  161.             EndIf
  162.     Else
  163.         If NOT EXISTS ENV:IDer.prefs
  164.             Copy >NIL: CUCD:S/IDer.prefs_OS2 ENV:IDer.prefs
  165.             EndIf
  166.         EndIf
  167.  
  168.     EndIf
  169. ;;;
  170. SetEnv CDInit TRUE
  171.  
  172. LAB END
  173.  
  174. ;;; Remove commands made resident earlier
  175. Resident >NIL: RequestChoice REMOVE
  176. Resident >NIL: rx REMOVE
  177. Resident >NIL: Version REMOVE
  178. ;;;
  179.